概要

本分步指南介绍如何从驱动器 m 删除 exchange 2000 可安装文件系统 (ifs) 映射。

ifs 提供了通过 win32 文件系统 api 来访问 exchange 2000 信息存储区这一访问方式。 exchange 2000 ifs 支持 \\.\backofficestorage\ 命名空间。 为兼容和方便起见，exchange 2000 也支持正常的驱动器命名空间，默认情况下是驱动器 m:\。 ifs 是作为通过标准文件系统接口访问 exchange 2000 信息存储区的一种方法被引入 exchange 2000 的。

不过，在某些情况下，使用 ifs 时可能会遇到一些问题。 正是因为这些问题，所以 microsoft 建议您删除到驱动器 m 的 ifs 映射，除非您有明确的原因不需要使用 ifs。 即使删除了驱动器 m 或其他驱动器盘符映射，\\.\backofficestorage\ 命名空间仍保持可用。

保留 ifs 映射的理由包括：

• 将“microsoft frontpage 扩展”用于“web 存储系统窗体”。
• 需要使用驱动器 m 映射进行开发。
• 使用 microsoft internet explorer 将驱动器 m 作为一个文件系统来搜索。

如果上面所列任意一条理由与您的 exchange 2000 环境相符，那么 microsoft 建议您在存在这些情况的服务器上保留此映射。

如要删除驱动器 m 映射，请使用本文中提供的脚本。

返回页首

创建驱动器 m 删除脚本

若要创建驱动器 m 删除脚本，请按照下列步骤操作：

1. 启动一个文本编辑器（如 microsoft 记事本），然后将下面的脚本复制并粘贴到编辑器中：

   @setlocal
   @if "%1"=="" goto usage
   @if "%1"=="/?" goto usage
   @if "%1"=="-?" goto usage
   @rem parameter is either a drive letter, or "none"
   
   @rem check for presence of adsutil.vbs
   @set adu=%systemdrive%\inetpub\adminscripts\adsutil.vbs
   @if exist %adu% goto stopsrv
   @echo this tool requires %adu% from the iis scripts.
   @goto fail
   
   :stopsrv
   @rem record what exchange services are currently running
   @echo off
   @set startsa=0
   @set startis=0
   @set startmta=0
   @set startwww=0
   for /f "delims=" %%a in (net start) do if "%%a" == "   microsoft exchange system attendant" set startsa=1 
   for /f "delims=" %%a in (net start) do if "%%a" == "   microsoft exchange information store" set startis=1 
   for /f "delims=" %%a in (net start) do if "%%a" == "   microsoft exchange mta stacks" set startmta=1 
   for /f "delims=" %%a in (net start) do if "%%a" == "   world wide web publishing service" set startwww=1 
   @echo on
   @echo stopping exchange services...
   net stop msexchangesa /y
   
   @echo stopping web services...
   net stop w3svc /y
   
   @if "%temp%" == "" set temp="c:\"
   @set regfile=%temp%\addm.reg
   @echo regedit4 > "%regfile%"
   @if "%1"=="none" goto deldrive
   @set drive=%1
   @set newdrive=%drive:~0,1%
   @echo adding %newdrive% drive mapping to the registry...
   @echo [hkey_local_machine\system\currentcontrolset\services\exifs\parameters] >> "%regfile%"
   @echo "driveletter"="%newdrive%" >> "%regfile%"
   @goto doregedit
   :deldrive
   @echo removing existing drive letter mapping...
   for /f "delims=\=>; tokens=1,2*" %%a in (subst) do (
     if /i "%%c" == " backofficestorage" (
       subst %%a /d
     )
   )
   @echo removing drive mapping from the registry...
   @echo [hkey_local_machine\system\currentcontrolset\services\exifs\parameters] >> "%regfile%"
   @echo "driveletter"="" >> "%regfile%"
   :doregedit
   @type %regfile%
   regedit -s "%regfile%"
   @if errorlevel 0 goto mb
   @goto fail
   
   :mb
   @echo touching the metabase to force update of exchange virtual roots...
   cscript %adu% delete /ds2mb/highwatermarks
   @goto restart
   
   :restart
   @echo restarting services...
   @if %startsa%==1  net start "microsoft exchange system attendant" /y
   @if %startis%==1  net start "microsoft exchange information store" /y
   @if %startmta%==1 net start "microsoft exchange mta stacks" /y
   @if %startwww%==1 net start w3svc /y
   @goto done
   
   :fail
   @echo the operation did not succeed.
   @goto end
   
   :done
   @echo done.
   @goto end
   
   :usage
   @echo usage: ifsdrive ^<drive-letter^>
   @echo        ifsdrive none
   @echo modifies or removes the mapping of exchange storage to a local drive letter.
   @echo specify a single letter to map exchange storage to that drive.
   @echo specify "none" (without quotes) to remove the mapping.
   @goto end
   
   :end
   @if not "%regfile%" == "" del "%regfile%"

2. 用 ifsdrive.cmd 这一文件名保存此文本文件。

返回页首

运行驱动器 m 删除脚本

创建驱动器 m 删除脚本后，您需要从 exchange 2000 服务器上使用命令来运行此脚本：

1. 打开一个命令窗口，然后将目录改到保存此脚本的文件夹。
2. 在命令提示符下，键入下面的命令以删除驱动器 m 映射：

   ifsdrive none

   备注： 为删除该映射，请使用完整的“none”一词。
3. 在脚本运行时，它下一步要执行的操作将显示出来。 脚本完成时，最后一行将显示“done”（完成）。
   
   备注： 此脚本先停止然后又启动 exchange 2000 消息传输代理 (mta)、exchange 2000 post office protocol 第 3 版 (pop3)、exchange 2000 internet message access protocol、version 4rev1 (imap4)、“exchange 2000 信息存储区”，以及“万维网发布服务”。
4. 如果误删了驱动器 m 映射，而现在因为前面所列原因之一又需要用它，可以在提示符下键入下面的命令（其中驱动器盘符 是 ifs 驱动器映射的盘符）：

   ifsdrive 驱动器盘符

   驱动器盘符 默认情况下是驱动器 m，但如果 ifs 驱动器映射曾被改为另一个驱动器盘符，那么请改用新的驱动器盘符。

删除 ifs 驱动器映射后，在 exchange 2000 信息存储区服务启动时，下面这一错误消息将记入应用程序事件日志：
您可以放心地忽略此错误信息；以后的 exchange 2000 版本中将删除此消息。

返回页首

参考

有关其他与保留驱动器 m 映射相关的一些问题的信息，请单击下面的文章编号以查看 microsoft 知识库中的文章：

271465 xadm： clients cannot access attachments after you back up drive m（备份驱动器 m 后客户机不能访问附件）

281673 prb： moving items within drive m of exchange can remove item properties（在 exchange 的驱动器 m 中移动项目会删除项目属性）

298924 xadm： do not back up or scan exchange 2000 drive m（不要备份或扫描 exchange 2000 驱动器 m）

299046 xadm： calendar items disappear from users folders（日历项目从用户的文件夹中消失）

303245 xcln： item count incorrect for messages with modified permission（修改权限后，消息的项目计数错误）

有关与驱动器 m 的防病毒扫描相关的一些问题（与保留驱动器 m 映射有关联）的其他信息，请单击下面的文章编号以查看 microsoft 知识库中的文章：

245822 xgen： recommendations for troubleshooting an exchange server computer with antivirus installed（针对安装了防病毒软件的 exchange server 计算机的故障排除建议）

298551 xadm： large number of transaction logs created（创建了大量事务日志）

文章整理：站长天空 网址：http://www.z6688.com/
以上信息与文章正文是不可分割的一部分,如果您要转载本文章,请保留以上信息，谢谢!